#!/usr/bin/expect
############################################################################
# Purpose: Test of srun functionality
#          Test of hostfile option (-hostfile).
#          
#
# Output:  "TEST: #.#" followed by "SUCCESS" if test was successful, OR
#          "FAILURE: ..." otherwise with an explanation of the failure, OR
#          anything else indicates a failure mode that must be investigated.
#
############################################################################
# Copyright (C) 2002-2006 The Regents of the University of California.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Danny Auble <da@llnl.gov>
# UCRL-CODE-217948.
# 
# This file is part of SLURM, a resource management program.
# For details, see <http://www.llnl.gov/linux/slurm/>.
#  
# SLURM is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
# 
# SLURM is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
# 
# You should have received a copy of the GNU General Public License along
# with SLURM; if not, write to the Free Software Foundation, Inc.,
# 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA.
############################################################################
source ./globals

set test_id     "1.52"
set exit_code   0
set num_nodes   2
set num_tasks   2
set node_count  0
set max_nodes   0
set task_count  0
set job_id      0
set hostfile    "test$test_id.hostfile"

print_header $test_id

exec $bin_rm -f $hostfile
if { [test_front_end] } {
	send_user "\nWARNING: This test incompatable with front-end Systems\n"
	exit $exit_code
}

#find out if we have enough nodes to test functionality
set def_part [default_partition]
spawn $scontrol show partition $def_part
expect {
	-re "not found" {
		send_user "\nFAILURE: partition $def_part doesn't exist\n"
		exit 1
	}
	-re "TotalNodes=($number)" {
		set node_count $expect_out(1,string)
		exp_continue
	}
	-re "MaxNodes=($number)" {
		set max_nodes $expect_out(1,string)
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: scontrol not responding\n"
		exit 1
	}
	eof {
		wait
	}
}
if { ($node_count < 2) || ($max_nodes < 2) } {
	send_user "WARNING: system must have at least 2 nodes to run this test on.\n" 
	exit $exit_code
}

set node0 0
set node1 0

for {set i 0} {$i<2} {incr i} {

	if { $i==1 } {
		if { $node0 == 0 || $node1 == 0 } {
			send_user "\nFAILURE: node names not set from \
				previous srun\n"
			exit 1
		}
		set env(SLURM_HOSTFILE) $hostfile
		set 1node0 $node0
		set 1node1 $node1
		set file [open $hostfile "w"]
		puts $file "$node1\n$node0"
		close $file
	}
	#
	# execute srun with a specific node count
	#
	set node0 ""
	set node1 ""
	spawn $srun -N2 -l $bin_printenv SLURMD_NODENAME
	expect {
		-re "($number): ($alpha_numeric)" {
			set task_id $expect_out(1,string)
			if {$task_id == 0} {
				set node0 $expect_out(2,string)
			} else {
				set node1 $expect_out(2,string)
			}
			exp_continue
		}
		-re "slurm job ($number)" {
			set job_id $expect_out(1,string)
			exp_continue
		}
		timeout {
			send_user "\nFAILURE: srun not responding\n"
			exec $scancel --quiet $job_id
			set exit_code 1
		}
		eof {
			wait
		}
	}
}

if { [string compare $node0 $1node1] } {
	send_user "\n FAILURE: tasks not distributed by hostfile\n"
	set exit_code 1
} elseif { [string compare $node1 $1node0] } {
	send_user "\nFAILURE: tasks not distributed by hostfile\n"
	set exit_code 1
}
if {$exit_code == 0} {
	send_user "\nSUCCESS\n"
}
exit $exit_code
