#!/usr/bin/expect
############################################################################
# Purpose: Test of SLURM functionality
#          Test of batch job requeue.
#
# Output:  "TEST: #.#" followed by "SUCCESS" if test was successful, OR
#          "FAILURE: ..." otherwise with an explanation of the failure, OR
#          anything else indicates a failure mode that must be investigated.
#
# Note:    This script generates and then deletes files in the working directory 
#          named test3.8.input, test.3.8.output, test.3.8.error, and 
#          test3.8.run.*
############################################################################
# Copyright (C) 2006 The Regents of the University of California.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Morris Jette <jette1@llnl.gov>
# UCRL-CODE-217948.
# 
# This file is part of SLURM, a resource management program.
# For details, see <http://www.llnl.gov/linux/slurm/>.
#  
# SLURM is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
# 
# SLURM is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
# 
# You should have received a copy of the GNU General Public License along
# with SLURM; if not, write to the Free Software Foundation, Inc.,
# 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA.
############################################################################
source ./globals

set test_id       "3.8"
set exit_code     0
set file_in       "test$test_id.input"
set file_out      "test$test_id.output"
set file_err      "test$test_id.error"
set file_flag_1   "test$test_id.run.1"
set file_flag_2   "test$test_id.run.2"
set file_flag_3   "test$test_id.run.3"
set job_id        0

print_header $test_id

if {[is_super_user] == 0} {
	send_user "\nWARNING: This test can't be run except as SlurmUser\n"
	exit 0
}

#
# Delete left-over input script plus stdout/err files
# Build input script file that runs two job steps
#
exec $bin_rm -f $file_in $file_out $file_err
exec $bin_rm -f $file_flag_1 $file_flag_2 $file_flag_3
make_bash_script $file_in "
    if   \[ -f $file_flag_2 \]
    then 
        $bin_touch $file_flag_3
    elif \[ -f $file_flag_1 \]
    then
        $bin_touch $file_flag_2
    else
        $bin_touch $file_flag_1
    fi
    $srun $bin_sleep 20
"

#
# Spawn a srun batch job that uses stdout/err and confirm their contents
#
set timeout $max_job_delay
spawn $srun --batch --output=$file_out --error=$file_err -t1 $file_in
expect {
	-re "jobid ($number) submitted" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: srun not responding\n"
		kill_srun
		set exit_code 1
		exp_continue
	}
	eof {
		wait
	}
}
if {$job_id == 0} {
	send_user "\nFAILURE: batch submit failure\n"
	exit 1
}

#
# Wait for job to begin, then requeue it
#
if {[wait_for_job $job_id "RUNNING"] != 0} {
	send_user "\nFAILURE: waiting for job to begin\n"
	set exit_code 1
}
exec $bin_sleep 2
spawn $scontrol requeue $job_id
expect {
	-re "error" {
		send_user "\nFAILURE: some scontrol error happened\n"
		set exit_code 1
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: scontrol not responding\n"
		set exit_code 1
	}
	eof {
		wait
	}
}

#
# Wait for job to complete and check for files
#
if {[wait_for_job $job_id "DONE"] != 0} {
	send_user "\nFAILURE: waiting for job to complete\n"
	set exit_code 1
}
if {[wait_for_file $file_flag_1] != 0} {
	send_user "\nFAILURE: file $file_flag_1 is missing\n"
	set exit_code 1
}
if {[wait_for_file $file_flag_2] != 0} {
	send_user "\nFAILURE: file $file_flag_2 is missing\n"
	set exit_code 1
}
if {[file exists $file_flag_3]} {
	send_user "\nFAILURE: file $file_flag_3 is found\n"
	set exit_code 1
}

#
# Now run the same test, but with job requeue disabled via the 
# srun --no-requeue option
#
set job_id        0

exec $bin_rm -f $file_flag_1 $file_flag_2 $file_flag_3

spawn $srun --no-requeue --batch --output=$file_out --error=$file_err -t1 $file_in
expect {
	-re "jobid ($number) submitted" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: srun not responding\n"
		kill_srun
		set exit_code 1
		exp_continue
	}
	eof {
		wait
	}
}
if {$job_id == 0} {
	send_user "\nFAILURE: batch submit failure\n"
	exit 1
}

#
# Wait for job to begin, then requeue it
#
if {[wait_for_job $job_id "RUNNING"] != 0} {
	send_user "\nFAILURE: waiting for job to begin\n"
	set exit_code 1
}
set disabled 0
exec $bin_sleep 2
spawn $scontrol requeue $job_id
expect {
	-re "error.*disabled" {
		set disabled 1
		send_user "This error was expected, no worries\n"
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: scontrol not responding\n"
		set exit_code 1
	}
	eof {
		wait
	}
}
if {$disabled == 0} {
	send_user "\nFAILURE: srun's --no-requeue option ignored\n"
	set exit_code 1
}

#
# Wait for job to complete and check for files
#
if {[wait_for_job $job_id "DONE"] != 0} {
	send_user "\nFAILURE: waiting for job to complete\n"
	set exit_code 1
}
if {[wait_for_file $file_flag_1] != 0} {
	send_user "\nFAILURE: file $file_flag_1 is missing\n"
	set exit_code 1
}
if {[file exists $file_flag_2]} {
	send_user "\nFAILURE: file $file_flag_2 is found\n"
	set exit_code 1
}
if {[file exists $file_flag_3]} {
	send_user "\nFAILURE: file $file_flag_3 is found\n"
	set exit_code 1
}

if {$exit_code == 0} {
	exec $bin_rm -f $file_in $file_out $file_err
	exec $bin_rm -f $file_flag_1 $file_flag_2 $file_flag_3
	send_user "\nSUCCESS\n"
}
exit $exit_code
