#!/usr/bin/expect
############################################################################
# Purpose: Test of SLURM functionality
#          Confirm that srun allocation mode (--allocate option).
#
# Output:  "TEST: #.#" followed by "SUCCESS" if test was successful, OR
#          "FAILURE: ..." otherwise with an explanation of the failure, OR
#          anything else indicates a failure mode that must be investigated.
############################################################################
# Copyright (C) 2002 The Regents of the University of California.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Morris Jette <jette1@llnl.gov>
# UCRL-CODE-217948.
# 
# This file is part of SLURM, a resource management program.
# For details, see <http://www.llnl.gov/linux/slurm/>.
#  
# SLURM is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
# 
# SLURM is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
# 
# You should have received a copy of the GNU General Public License along
# with SLURM; if not, write to the Free Software Foundation, Inc.,
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA.
############################################################################
source ./globals

set test_id            "1.17"
set exit_code          0
set job_id             0
set slurm_jobid        0

print_header $test_id

#
# Submit a slurm allocate job
# Interactively print $SLURM_JOBID
#
set timeout $max_job_delay
set match 0
set srun_pid [spawn $srun --allocate --verbose -t1]
expect {
	-re "jobid ($number).*" {
		set job_id $expect_out(1,string)
		send "$bin_echo MY_ID=\$SLURM_JOBID \n"
		exp_continue
	}
	-re "MY_ID=($number)" {
		set slurm_jobid $expect_out(1,string)
		send "exit 2\n"
		exp_continue
	}
	-re "MY_ID=" {
#		no environment variable
		send "exit 2\n"
		exp_continue
	}
	-re "\[Ee\]xit 2" {
		send_user "This error was expected, no worries\n"
		set match 1
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: srun not responding\n"
		slow_kill $srun_pid
		set exit_code 1
	}
	eof {
		wait
	}
}


#
# Confirm the job_ids match.
#
if { $job_id == 0 } {
	send_user "\nFAILURE: srun --allocate failure\n"
	set exit_code 1
} else {
	if { $job_id != $slurm_jobid } {
		send_user "\nFAILURE: srun job_id mis-match\n"
		set exit_code 1
	}
}

#
# Confirm exit code is propogated
#
if { $match != 1 } {
	send_user "\nFAILURE: srun exit code not reported\n"
	set exit_code 1
}

if { $exit_code == 0 } {
	send_user "\nSUCCESS\n"
}
exit $exit_code
